home *** CD-ROM | disk | FTP | other *** search
/ Resource for Source: C/C++ / Resource for Source - C-C++.iso / codelib2 / v_02_05 / 2n05026a < prev    next >
Encoding:
Text File  |  1995-11-01  |  7.4 KB  |  396 lines
  1.         title    Net_CD
  2.         page    59, 132
  3. ;
  4. ; File:        Net_CD.ASM
  5. ; Purpose:    Workstation client device driver for
  6. ;        remote CDROM access
  7. ; Description:    This file contains the device driver 
  8. ;        header and the standard strategy and
  9. ;        interrupt routines, as well as some
  10. ;        of the initialization code and 
  11. ;        interfaces to BIOS, DOS, and NetBIOS
  12. ;        functions.
  13. ;
  14.  
  15.         subttl    Structure definitions
  16.         page    +
  17. ;
  18. ; Standard device driver header
  19. ;
  20. rh        struc
  21.  
  22. rh_length    db    ?    ; header size, bytes
  23. rh_unit        db    ?    ; block dev. unit #
  24. rh_command    db    ?    ; device command code
  25. rh_status    dw    ?    ; device command status
  26. rh_reserved    db     8 dup (?)
  27. rh        ends
  28.  
  29. ;
  30. ; INIT command header extensions
  31. ;
  32. rh0        struc
  33.  
  34. rh0_rh        db    size rh dup (?)
  35. rh0_numUnits    db    ?    ; number block units
  36. rh0_brkAddress    dd    ?    ; end of driver address
  37. rh0_bpb        dd    ?    ; BIOS parameter block
  38. rh0_devNumber    db    ?    ; block device number 
  39. rh0        ends
  40.  
  41.         subttl     'C' Driver Functions
  42.         page    +
  43. ;
  44. ; Externally linked 'C' function declarations
  45. ;
  46. extrn        _UnknownCommand:near
  47. extrn        _Initialize:near
  48. extrn        _DevOpen:near
  49. extrn        _DevClose:near
  50. extrn        _IOInput:near
  51. extrn        _IOOutput:near
  52.  
  53. extrn        _ReadLong:near
  54. extrn        _ReadPrefetch:near
  55. extrn        _Seek:near
  56.  
  57.  
  58.         subttl     Segment Declarations
  59.         page    +
  60. ;
  61. ; Segments are declared with _DATA first to allow the
  62. ; device driver header to appear at offset 0 within the
  63. ; driver at load time.  _BSS and CONST are present to
  64. ; handle normal MS-C code emissions.  _TEXT and INIT are
  65. ; declared last to allow for easy discarding of the
  66. ; driver Initialize routine.
  67. ;
  68. DGROUP    group    _DATA, _BSS, CONST, _TEXT, INIT
  69.  
  70. _DATA        segment word PUBLIC 'DATA'
  71.         assume ds:DGROUP
  72. _DATA        ends
  73.  
  74. _BSS        segment word PUBLIC 'BSS'
  75.         assume ds:DGROUP
  76. _BSS        ends
  77.  
  78. CONST        segment word PUBLIC 'CONST'
  79.         assume ds:DGROUP
  80. CONST        ends
  81.  
  82. _TEXT        segment word PUBLIC 'CODE'
  83.         assume cs:DGROUP, ds:DGROUP
  84. _TEXT        ends
  85.  
  86. INIT        segment word PUBLIC 'INIT'
  87.         assume cs:DGROUP, ds:DGROUP
  88. INIT        ends
  89.  
  90.         subttl    Net_CD Data Segment
  91.         page    + 
  92.  
  93. _DATA        segment
  94.  
  95. Net_CD:
  96.  
  97. ; 
  98. ; Public declarations for initialization code 
  99. ; 
  100.         PUBLIC    _DevHeader 
  101. ; 
  102. ; Device driver header with CDROM extension fields 
  103. ; 
  104. _DevHeader    label    word
  105.         dd    -1    ; next driver
  106.         dw    0c800h    ; device attributes
  107.         dw    DGROUP:DevStrategy
  108.         dw    DGROUP:DevInterrupt
  109.         db    'NET-CD  '
  110.         dw    0    ; CDROM reserved
  111.         db    0    ; CDROM drive letter
  112.         db    1    ; number of units
  113.  
  114. ;
  115. ; Local data for function dispatcher
  116. ;
  117. rh_offset    dw    ?    ; Req Hdr pointer
  118. rh_segment    dw    ?
  119.  
  120. save_sp        dw    ?    ; old stack save
  121. save_ss        dw    ?    ;   area
  122.  
  123. local_stack    dw    256 dup ('s')    ; local stack
  124. top_stack    dw    DGROUP:$    ;   me and 'C'
  125.  
  126. ;
  127. ; Driver standard commands jump table
  128. ;
  129. DevCmdTbl    label    word
  130.         dw    DGROUP:_Initialize
  131.         dw    DGROUP:_UnknownCommand
  132.         dw    DGROUP:_UnknownCommand
  133.         dw    DGROUP:_IOInput
  134.         dw    DGROUP:_UnknownCommand
  135.         dw    DGROUP:_UnknownCommand
  136.         dw    DGROUP:_UnknownCommand
  137.         dw    DGROUP:_UnknownCommand
  138.         dw    DGROUP:_UnknownCommand
  139.         dw    DGROUP:_UnknownCommand
  140.         dw    DGROUP:_UnknownCommand
  141.         dw    DGROUP:_UnknownCommand
  142.         dw    DGROUP:_IOOutput
  143.         dw    DGROUP:_DevOpen
  144.         dw    DGROUP:_DevClose
  145.         dw    DGROUP:_UnknownCommand
  146.  
  147. ;
  148. ; CDROM extended commands jump table
  149. ;
  150. DevExtCmdTbl    label     word
  151.         dw    DGROUP:_ReadLong
  152.         dw    DGROUP:_UnknownCommand
  153.         dw    DGROUP:_ReadPrefetch
  154.         dw    DGROUP:_Seek
  155.         dw    DGROUP:_UnknownCommand
  156.         dw    DGROUP:_UnknownCommand
  157.         dw    DGROUP:_UnknownCommand
  158.         dw    DGROUP:_UnknownCommand
  159.         dw    DGROUP:_UnknownCommand
  160.  
  161.  
  162. _DATA        ends
  163.  
  164.         subttl     Net_CD Text Segment
  165.         page    +
  166.  
  167. ;
  168. ; Assembly language portion of the Text segment contains
  169. ; the standard driver Strategy and Interrupt routines as
  170. ; well an interface routine to NetBIOS
  171. ;
  172.  
  173. _TEXT        segment
  174.  
  175. ;
  176. ; Device Strategy routine
  177. ;   Save request header pointer for subsequent call to
  178. ;   Interrupt routine.
  179. ;
  180.  
  181. DevStrategy    proc    far
  182.  
  183.         mov    cs:rh_offset, bx
  184.         mov    cs:rh_segment, es
  185.         ret
  186.  
  187. DevStrategy    endp
  188.  
  189. ;
  190. ; Device Interrupt routine
  191. ;   DevInterrupt sets up a stack for the 'C' routines
  192. ;   and validates the command before dispatching it to
  193. ;   an appropriate handler.
  194. ;
  195.  
  196. DevInterrupt    proc    far
  197.  
  198.         ; save calling context
  199.         pushf    
  200.         push    ax
  201.         push    bx
  202.         push    cx
  203.         push    dx
  204.         push    si
  205.         push    di
  206.         push    ds
  207.         push    es
  208.  
  209.         ; setup addressing for local and 'C'
  210.         mov    ax, cs
  211.         mov    ds, ax
  212.  
  213.         ; switch to local stack
  214.         mov    save_sp, sp
  215.         mov    save_ss, ss
  216.         mov    ss, ax
  217.         mov    sp, top_stack
  218.  
  219.         ; reload request header pointer
  220.         mov    ax, rh_segment
  221.         mov    es, ax
  222.         mov    bx, rh_offset
  223.  
  224.         ; prepare for call to handlers
  225.         push    es
  226.         push    bx
  227.  
  228.         ; process command
  229.         mov    al, es:[bx].rh_command
  230.         xor    ah, ah
  231.         cmp    al, 128        ; CDROM cmd?
  232.         jae    IntCDROMCmd
  233.  
  234.         cmp    al, 15        ; valid cmd?
  235.         jb    IntStdCmd
  236.  
  237. IntInvalid:    mov    ax, 8013h    ; set unknown
  238.         jmp    IntExit
  239.  
  240. IntCDROMCmd:    sub    al, 128
  241.         cmp    al, 8        ; valid CDROM?
  242.         ja    IntInvalid
  243.  
  244.         shl    ax, 1        ; dispatch to
  245.         mov    si, ax        ;   handler
  246.         call    DevExtCmdTbl[si]
  247.         jmp    IntExit
  248.  
  249. IntStdCmd:    shl    ax, 1        ; dispatch to
  250.         mov    si, ax        ;   handler
  251.         call    DevCmdTbl[si]
  252.  
  253.         ; set up exit status
  254. IntExit:    pop    bx
  255.         pop    es
  256.         mov    es:[bx].rh_status, ax
  257.  
  258.         ; reset calling context
  259.         mov    ss, save_ss
  260.         mov    sp, save_sp
  261.  
  262.         pop    es
  263.         pop    ds
  264.         pop    di
  265.         pop    si
  266.         pop    dx
  267.         pop    cx
  268.         pop    bx
  269.         pop    ax
  270.         popf
  271.  
  272.         ret
  273.         even
  274. DevInterrupt    endp
  275.  
  276. ;
  277. ; _NetBIOS : void NetBIOS (NCB far *)
  278. ;   Call NetBIOS at INT 5C.  This function assumes
  279. ;   NetBIOS has been loaded and makes no checks to
  280. ;   verify that.
  281. ;
  282.  
  283.         PUBLIC    _NetBIOS
  284. _NetBIOS    proc    near
  285.         push    bp
  286.         mov    bp, sp
  287.  
  288.         ; set es:bx to point to NCB and go
  289.         push    bx
  290.         push    es
  291.         mov    bx, [bp+4]
  292.         mov    ax, [bp+6]
  293.         mov    es, ax
  294.         int    5ch
  295.  
  296.         pop    bx
  297.         pop    es
  298.         pop    bp
  299.         ret
  300. _NetBIOS    endp
  301.  
  302.  
  303. _TEXT        ends
  304.  
  305.         subttl    Net_CD INIT Segment
  306.         page    +
  307.  
  308. ;
  309. ; Driver INIT segment
  310. ;   Having the Initialize function linked last guarantees
  311. ;   that it appears last in the _TEXT segment.  Since this
  312. ;   segment comes after the _TEXT segment when Initializes
  313. ;   tells DOS to discard the data from _Initialize on all
  314. ;   of this segment will disappear also.
  315. ;
  316.  
  317. INIT        segment
  318.  
  319. ;
  320. ; _DisplayString : void DisplayString (char *)
  321. ;   Displays a string using DOS function 9.  This function
  322. ;   may only be used during device driver initialization.
  323. ;
  324.  
  325.         PUBLIC    _DisplayString
  326. _DisplayString    proc    near
  327.         
  328.         push    bp
  329.         mov    bp, sp
  330.  
  331.         push    di
  332.         push    si
  333.  
  334.         mov    ah, 9        ; display str$
  335.         mov    dx, [bp+4]    ; string ptr.
  336.         int    21h
  337.  
  338.         pop    si
  339.         pop    di
  340.         pop    bp
  341.         ret
  342. _DisplayString    endp
  343.  
  344. ;
  345. ; _SetEndAddress : void SetEndAddress (struc rh0 far *)
  346. ;   Set the ending address of the device driver in the 
  347. ;   Initialize request header.  The location of
  348. ;   _Initialize is taken to be the location at which
  349. ;   discardable data begins, which will effectively
  350. ;   eliminate the INIT segment also.
  351. ;
  352.         
  353.         PUBLIC    _SetEndAddress
  354. _SetEndAddress    proc    near
  355.  
  356.         push    bp
  357.         mov    bp, sp
  358.  
  359.         ; get request header in es:di
  360.         push    di
  361.         mov    di, [bp+4]
  362.         mov    ax, [bp+6]
  363.         mov    es, ax
  364.  
  365.         ; set address in rh0_brkAddress
  366.     mov    word ptr es:[di].rh0_brkAddress, offset DGROUP:_Initialize
  367.     mov    word ptr es:[di].rh0_brkAddress+2, cs
  368.  
  369.         pop    di
  370.         pop    bp
  371.         ret
  372. _SetEndAddress    endp
  373.  
  374.  
  375. ;
  376. ; Discardable initialization data
  377. ;
  378.         PUBLIC    _banner, __acrtused
  379. ;
  380. ; Device Driver loading banner
  381. ;
  382. _banner        db     0dh, 0ah
  383.         db    'Net_CD.SYS:  Workstation Client'
  384.         db    ' Software Loaded'
  385.         db    0dh, 0ah, '$', 0
  386.  
  387. ;
  388. ; So MSC doesn't complain - set a CRT being used
  389. ;
  390. __acrtused    dw    1
  391.  
  392. INIT        ends
  393.  
  394.  
  395.         end     Net_CD
  396.